Roku 애플리케이션에 대한 광고 추적

Roku Video 에이전트는 두 가지 다른 Ad API를 통해 광고 이벤트 모니터링을 제공합니다.

전제 조건

광고 추적을 활성화하기 전에:

Roku 에이전트 설치완료
뉴렐릭 에이전트를 초기화합니다(아래 예에서는 m.nr 으로 참조됨).

Roku 광고 프레임워크(RAF)

RAF는 NRAgent에 통합되어 있습니다. 추가 파일은 필요하지 않습니다.

RAF 추적을 활성화합니다.

NewRelic("ACCOUNT ID", "LICENSE KEY") 으로 생성된 NRAgent 객체를 필드를 사용하여 Ads 작업에 전달합니다. 광고 작업 내에서 다음을 수행하십시오.

adIface = Roku_Ads()

' Ad Iface setup code...

logFunc = Function(obj = Invalid as Dynamic, evtType = invalid as Dynamic, ctx = invalid as Dynamic)
    'Call RAF tracker, passing the event and context
    nrTrackRAF(obj, evtType, ctx)
End Function

' m.top.nr is the reference to the field where we have the NRAgent object
adIface.setTrackingCallback(logFunc, m.top.nr)

전체 사용 예시를 보려면 Roku 에이전트 패키지의 파일 VideoScene.brs (함수 setupVideoWithAds()) 및 AdsTask.brs 를 확인하세요.

구글 IMA

필요한 파일을 복사하세요

프로젝트 디렉토리에 다음 파일들이 포함되어 있는지 확인하십시오.

components/NewRelicAgent/trackers
    IMATracker.brs
    IMATracker.xml
source/
    IMATrackerInterface.brs

IMA 트래커 생성

IMA Tracker 객체를 생성합니다.

tracker = IMATracker(m.nr)

여기서 m.nr 은 NRAgent 객체입니다.

광고 추적 설정

추적기 객체를 필드를 사용하여 IMA SDK 작업에 전달하고 작업 XML에 스크립트 IMATrackerInterface.brs 을 포함합니다. 작업 내에서 다음과 같은 추적을 설정하세요.

광고 시간 추적:

m.player.adBreakStarted = Function(adBreakInfo as Object)
    ' Ad break start code...

    ' Send AD_BREAK_START
    nrSendIMAAdBreakStart(m.top.tracker, adBreakInfo)
End Function

m.player.adBreakEnded = Function(adBreakInfo as Object)
    ' Ad break end code...

    ' Send AD_BREAK_END
    nrSendIMAAdBreakEnd(m.top.tracker, adBreakInfo)
End Function

광고 이벤트 추적:

m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)

Function startCallback(ad as Object) as Void
    ' Send AD_START
    nrSendIMAAdStart(m.top.tracker, ad)
End Function

Function firstQuartileCallback(ad as Object) as Void
    ' Send AD_QUARTILE (first)
    nrSendIMAAdFirstQuartile(m.top.tracker, ad)
End Function

Function midpointCallback(ad as Object) as Void
    ' Send AD_QUARTILE (midpoint)
    nrSendIMAAdMidpoint(m.top.tracker, ad)
End Function

Function thirdQuartileCallback(ad as Object) as Void
    ' Send AD_QUARTILE (third)
    nrSendIMAAdThirdQuartile(m.top.tracker, ad)
End Function

Function completeCallback(ad as Object) as Void
    ' Send AD_END
    nrSendIMAAdEnd(m.top.tracker, ad)
End Function

여기서 m.top.tracker 작업에 전달된 추적 객체입니다.

전체 사용 예시를 보려면 Roku 에이전트 패키지의 파일 VideoScene.brs (함수 setupVideoWithIMA()) 및 imasdk.brs 를 확인하세요.

사용자의 편의를 위해 제공되는 기계 번역입니다.