Roku アプリケーションの広告トラッキング

Roku Video エージェントは、2 つの異なる広告 API を通じて広告イベント監視を提供します。

前提条件

広告トラッキングを有効にする前に：

Roku エージェントの完全なインストール
New Relicエージェントを初期化します(以下の例ではm.nrとして参照されます)

Roku 広告フレームワーク (RAF)

RAFはNRAgentに統合されています。追加ファイルは必要ありません。

RAFトラッキングを有効にする

NRAgent オブジェクト (NewRelic("ACCOUNT ID", "LICENSE KEY")で作成) をフィールドを使用して広告タスクに渡します。広告タスク内で、以下の操作を実行します。

adIface = Roku_Ads()

' Ad Iface setup code...

logFunc = Function(obj = Invalid as Dynamic, evtType = invalid as Dynamic, ctx = invalid as Dynamic)
    'Call RAF tracker, passing the event and context
    nrTrackRAF(obj, evtType, ctx)
End Function

' m.top.nr is the reference to the field where we have the NRAgent object
adIface.setTrackingCallback(logFunc, m.top.nr)

完全な使用例については、Roku エージェントパッケージのファイルVideoScene.brs (関数setupVideoWithAds()) とAdsTask.brsを確認してください。

グーグル

必要なファイルをコピーする

プロジェクトディレクトリに以下のファイルが含まれていることを確認してください。

components/NewRelicAgent/trackers
    IMATracker.brs
    IMATracker.xml
source/
    IMATrackerInterface.brs

IMAトラッカーを作成する

IMA トラッカーオブジェクトを作成します。

tracker = IMATracker(m.nr)

ここで、 m.nrは NRAgent オブジェクトです。

広告トラッキングを設定する

トラッカーオブジェクトをフィールドを使用して IMA SDK タスクに渡し、タスク XML にスクリプトIMATrackerInterface.brsを含めます。タスク内で、以下の追跡設定を行います。

広告ブレークを追跡する:

m.player.adBreakStarted = Function(adBreakInfo as Object)
    ' Ad break start code...

    ' Send AD_BREAK_START
    nrSendIMAAdBreakStart(m.top.tracker, adBreakInfo)
End Function

m.player.adBreakEnded = Function(adBreakInfo as Object)
    ' Ad break end code...

    ' Send AD_BREAK_END
    nrSendIMAAdBreakEnd(m.top.tracker, adBreakInfo)
End Function

広告イベントを追跡する：

m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)

Function startCallback(ad as Object) as Void
    ' Send AD_START
    nrSendIMAAdStart(m.top.tracker, ad)
End Function

Function firstQuartileCallback(ad as Object) as Void
    ' Send AD_QUARTILE (first)
    nrSendIMAAdFirstQuartile(m.top.tracker, ad)
End Function

Function midpointCallback(ad as Object) as Void
    ' Send AD_QUARTILE (midpoint)
    nrSendIMAAdMidpoint(m.top.tracker, ad)
End Function

Function thirdQuartileCallback(ad as Object) as Void
    ' Send AD_QUARTILE (third)
    nrSendIMAAdThirdQuartile(m.top.tracker, ad)
End Function

Function completeCallback(ad as Object) as Void
    ' Send AD_END
    nrSendIMAAdEnd(m.top.tracker, ad)
End Function

ここで、 m.top.trackerはタスクに渡されるトラッカーオブジェクトです。

完全な使用例については、Roku エージェントパッケージのファイルVideoScene.brs (関数setupVideoWithIMA()) とimasdk.brsを確認してください。

この機械翻訳は、参考として提供されています。