Seguimiento de anuncios para la aplicación Roku

El agente de Roku Video proporciona monitoreo de eventos publicitarios a través de dos API de anuncios diferentes:

Requisitos previos

Antes de habilitar el seguimiento de anuncios:

Complete la instalación del agente de Roku
Inicialice el agente de New Relic (referenciado como m.nr en los siguientes ejemplos)

Marco de publicidad de Roku (RAF)

RAF está integrado en el NRAgent. No se requieren archivos adicionales.

Habilitar el seguimiento de RAF

Pasa el objeto NRAgent (creado con NewRelic("ACCOUNT ID", "LICENSE KEY")) a la tarea de Ads usando un campo. Dentro de la tarea Ads, realice lo siguiente:

adIface = Roku_Ads()

' Ad Iface setup code...

logFunc = Function(obj = Invalid as Dynamic, evtType = invalid as Dynamic, ctx = invalid as Dynamic)
    'Call RAF tracker, passing the event and context
    nrTrackRAF(obj, evtType, ctx)
End Function

' m.top.nr is the reference to the field where we have the NRAgent object
adIface.setTrackingCallback(logFunc, m.top.nr)

Para ver un ejemplo de uso completo, consulte los archivos VideoScene.brs (función setupVideoWithAds()) y AdsTask.brs en el paquete del agente de Roku.

IMA de Google

Copiar los archivos requeridos

Asegúrese de que los siguientes archivos estén incluidos en el directorio de su proyecto:

components/NewRelicAgent/trackers
    IMATracker.brs
    IMATracker.xml
source/
    IMATrackerInterface.brs

Crear rastreador de IMA

Cree el objeto IMA Tracker:

tracker = IMATracker(m.nr)

Donde m.nr es el objeto NRAgent.

Configurar el seguimiento de anuncios

Pasa el objeto tracker a la tarea del SDK de IMA mediante un campo e incluye el script IMATrackerInterface.brs en el XML de la tarea. Dentro de la tarea, configure el siguiente seguimiento:

Rastrear pausas publicitarias:

m.player.adBreakStarted = Function(adBreakInfo as Object)
    ' Ad break start code...

    ' Send AD_BREAK_START
    nrSendIMAAdBreakStart(m.top.tracker, adBreakInfo)
End Function

m.player.adBreakEnded = Function(adBreakInfo as Object)
    ' Ad break end code...

    ' Send AD_BREAK_END
    nrSendIMAAdBreakEnd(m.top.tracker, adBreakInfo)
End Function

Rastrear eventos de anuncios:

m.streamManager.addEventListener(m.sdk.AdEvent.START, startCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.FIRST_QUARTILE, firstQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.MIDPOINT, midpointCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.THIRD_QUARTILE, thirdQuartileCallback)
m.streamManager.addEventListener(m.sdk.AdEvent.COMPLETE, completeCallback)

Function startCallback(ad as Object) as Void
    ' Send AD_START
    nrSendIMAAdStart(m.top.tracker, ad)
End Function

Function firstQuartileCallback(ad as Object) as Void
    ' Send AD_QUARTILE (first)
    nrSendIMAAdFirstQuartile(m.top.tracker, ad)
End Function

Function midpointCallback(ad as Object) as Void
    ' Send AD_QUARTILE (midpoint)
    nrSendIMAAdMidpoint(m.top.tracker, ad)
End Function

Function thirdQuartileCallback(ad as Object) as Void
    ' Send AD_QUARTILE (third)
    nrSendIMAAdThirdQuartile(m.top.tracker, ad)
End Function

Function completeCallback(ad as Object) as Void
    ' Send AD_END
    nrSendIMAAdEnd(m.top.tracker, ad)
End Function

Donde m.top.tracker es el objeto rastreador pasado a la tarea.

Para ver un ejemplo de uso completo, consulte los archivos VideoScene.brs (función setupVideoWithIMA()) y imasdk.brs en el paquete del agente de Roku.

Te ofrecemos esta traducción automática para facilitar la lectura.